kraken/kraken.krak

import io:*
import grammer:*
import parser:*
import ast_transformation:*
import string:*
import util:*
import symbol:*
import tree:*
import serialize:*
import c_generator:*
import interpreter:*
import os:*
import compiler_version


fun main(argc: int, argv: **char):int {
    if (argc <= 1) {
        error("No input file!\n Call with one argument (the input file), or two arguments (input file and output name)")
    } else if (string(argv[1]) == "-v" || string(argv[1]) == "--version") {
        println(compiler_version::version_string)
        exit(0)
    }
    var input_file_offset = 1
    var interpret_instead = false
    if (string(argv[1]) == "-i") {
        interpret_instead = true
        input_file_offset++
    }
    var kraken_file_name = string(argv[input_file_offset])
    var executable_name = string(".").join(kraken_file_name.split('.').slice(0,-2))
    if (argc == input_file_offset+2)
        executable_name = string(argv[input_file_offset+1])
    // delay construction until we either load it or copy construct it
    var gram: grammer
    var base_dir = string("/").join(string(argv[0]).split('/').slice(0,-2))
    var file_name = base_dir + "/krakenGrammer.kgm"
    var compiled_name = file_name + string(".comp_new")
    var compiled_version = 1
    var file_contents = read_file(file_name)
    var loaded_and_valid = false

    if (file_exists(compiled_name)) {
        /*println("cached file exists")*/
        var pos = 0
        var binary = read_file_binary(compiled_name)
        /*println("read file!")*/
        var saved_version = 0
        unpack(saved_version, pos) = unserialize<int>(binary, pos)
        if (saved_version == compiled_version) {
            var cached_contents = string()
            unpack(cached_contents, pos) = unserialize<string>(binary, pos)
            if (cached_contents == file_contents) {
                /*println("loaded_and_valid, using cached version!")*/
                loaded_and_valid = true
                pos = gram.unserialize(binary, pos)
            } else println("contents different")
        } else println("version number different")
    } else {
        println("cached file does not exist")
    }
    if (!loaded_and_valid) {
        println("Not loaded_and_valid, re-generating and writing out")
        /*gram = load_grammer(file_contents)*/
        // since we now don't construct before hand
        gram.copy_construct(&load_grammer(file_contents))
        println("grammer loaded, calculate_first_set")
        gram.calculate_first_set()
        println("grammer loaded, calculate_state_automaton")
        gram.calculate_state_automaton()
        println("calculated, writing out")
        write_file_binary(compiled_name, serialize(compiled_version) + serialize(file_contents) + serialize(gram))
        println("done writing")
    }

    var parse.construct(gram): parser
    var ast_pass.construct(): ast_transformation
    var importer.construct(parse, ast_pass, vector(string(), base_dir + "/stdlib/")): importer
    importer.import(kraken_file_name)
    if (interpret_instead) {
        println("Interpreting!")
        var interpret.construct(importer.name_ast_map, importer.ast_pass.ast_to_syntax): interpreter
        interpret.call_main()
    } else {
        println("Generating C")
        var c_generator.construct(): c_generator
        var c_output_pair = c_generator.generate_c(importer.name_ast_map, importer.ast_pass.ast_to_syntax)
        var kraken_c_output_name = kraken_file_name + ".c"
        write_file(kraken_c_output_name, c_output_pair.first)
        /*println(string("linker string: ") + c_output_pair.second)*/
        var compile_string = "cc -g -O3 -Wno-int-to-pointer-cast -Wno-pointer-to-int-cast -std=c99 " + c_output_pair.second + " " + kraken_c_output_name + " -o " + executable_name
        println(compile_string)
        system(compile_string)
    }

    return 0
}